Shiro/build.gradle.kts at main · MisakaTAT/Shiro · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
@file:Suppress("SpellCheckingInspection")

import org.jreleaser.model.Active

group = "com.mikuac"
version = "2.5.5"

val mavenArtifactResolver = "1.9.27"
val mavenResolverProvider = "3.9.15"
val junit = "6.1.2"

plugins {
    signing
    `java-library`
    `maven-publish`
    id("org.jreleaser") version "1.25.0"
    id("io.freefair.lombok") version "9.5.0"
    id("org.springframework.boot") version "4.1.0"
    id("io.spring.dependency-management") version "1.1.7"
}

java {
    withSourcesJar()
    withJavadocJar()
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

tasks {
    withType<Test> {
        useJUnitPlatform()
    }

    withType<JavaCompile> {
        options.encoding = "UTF-8"
    }

    withType<Javadoc> {
        val opts = options as StandardJavadocDocletOptions
        opts.encoding = "UTF-8"
        opts.addBooleanOption("Xdoclint:none", true)
    }

    named<Jar>("jar") {
        // Remove `plain` postfix from jar file name
        archiveClassifier = ""
        enabled = true
    }

    named("bootJar") {
        enabled = false
    }
}

repositories {
    maven { url = uri("https://maven.aliyun.com/repository/public/") }
    mavenCentral()
}

dependencies {
    api("org.springframework.boot:spring-boot-starter-websocket")

    api("org.apache.maven:maven-resolver-provider:$mavenResolverProvider")
    api("org.apache.maven.resolver:maven-resolver-supplier:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-connector-basic:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-transport-file:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-transport-http:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-impl:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-api:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-util:$mavenArtifactResolver")
    api("org.apache.maven.resolver:maven-resolver-spi:$mavenArtifactResolver")

    annotationProcessor("org.springframework.boot:spring-boot-configuration-processor")

    testImplementation("org.springframework.boot:spring-boot-starter-test")
    testImplementation("org.junit.jupiter:junit-jupiter:$junit")
}

val stagingDirectory: Directory = layout.buildDirectory.dir("staging-deploy").get()

fun MavenPom.populate() {
    packaging = "jar"
    group = project.group
    name = project.name
    version = project.version
    description = "基于OneBot协议的QQ机器人快速开发框架"
    url = "https://github.com/MisakaTAT/Shiro"
    scm {
        url = "https://github.com/MisakaTAT/Shiro"
        connection = "scm:git:git://github.com/MisakaTAT/Shiro.git"
        developerConnection = "scm:git:ssh://github.com/MisakaTAT/Shiro.git"
    }
    licenses {
        license {
            name = "GNU Affero General Public License v3.0"
            url = "https://github.com/MisakaTAT/Shiro/blob/main/LICENSE"
            distribution = "repo"
        }
    }
    developers {
        developer {
            id = "MisakaTAT"
            name = "MisakaTAT"
            email = "i@mikuac.com"
        }
    }
}

publishing {
    publications {
        register<MavenPublication>("Release") {
            from(components["java"])
            artifactId = project.name
            groupId = project.group as String
            version = project.version as String
            pom.populate()
        }
    }

    repositories.maven {
        url = stagingDirectory.asFile.toURI()
    }
}

jreleaser {
    signing {
        active = Active.RELEASE
        armored = true
    }
    deploy {
        maven {
            mavenCentral {
                register("sonatype") {
                    active = Active.RELEASE
                    url = "https://central.sonatype.com/api/v1/publisher"
                    stagingRepository(stagingDirectory.asFile.relativeTo(projectDir).path)
                }
            }
        }
    }
}

tasks.jar {
    manifest {
        attributes(
            "Implementation-Title" to project.name,
            "Implementation-Version" to project.version
        )
    }
}