grpc-kotlin/stub/build.gradle.kts at master · grpc/grpc-kotlin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
import com.google.protobuf.gradle.*

plugins { alias(libs.plugins.dokka) }

repositories {
  google()
  mavenCentral()

  // for Dokka
  maven("https://maven.pkg.jetbrains.space/public/p/kotlinx-html/maven")
}

dependencies {
  // Kotlin
  implementation(kotlin("stdlib"))
  implementation(libs.kotlinx.coroutines.core.jvm)

  // Grpc
  api(libs.grpc.stub)

  // Java
  api(libs.javax.annotation.api)

  // Testing
  testImplementation(libs.junit)
  testImplementation(libs.junit.jupiter.engine)
  testImplementation(libs.truth.proto.extension)
  testImplementation(libs.grpc.protobuf)
  testImplementation(libs.grpc.testing)
  testImplementation(libs.grpc.inprocess)
}

java {
  withSourcesJar()
  toolchain { languageVersion = JavaLanguageVersion.of(17) }
}

protobuf {
  protoc { artifact = libs.protoc.asProvider().get().toString() }
  plugins {
    id("grpc") { artifact = libs.protoc.gen.grpc.java.get().toString() }
    id("grpckt") {
      path = project(":compiler").tasks.jar.get().archiveFile.get().asFile.absolutePath
    }
  }
  generateProtoTasks {
    all().forEach {
      if (it.name.startsWith("generateTestProto")) {
        it.dependsOn(":compiler:jar")
      }

      it.plugins {
        id("grpc")
        id("grpckt")
      }
    }
  }
}

dokka {
  dokkaSourceSets.main {
    reportUndocumented = true

    sourceLink {
      localDirectory.set(file("src/main/java"))
      remoteUrl("https://github.com/grpc/grpc-kotlin/blob/master/stub/src/main/java")
      remoteLineSuffix.set("#L")
    }

    externalDocumentationLinks.register("grpc-java-docs") {
      url("https://grpc.github.io/grpc-java/javadoc/")
      packageListUrl("https://grpc.github.io/grpc-java/javadoc/element-list")
    }
    externalDocumentationLinks.register("kotlinx.coroutines-docs") {
      url("https://kotlinlang.org/api/kotlinx.coroutines/")
    }

    perPackageOption {
      matchingRegex.set("io.grpc.testing.*")
      suppress.set(true)
    }

    perPackageOption {
      matchingRegex.set("io.grpc.kotlin.generator.*")
      suppress.set(true)
    }
  }
}

val javadocJar by
  tasks.registering(Jar::class) {
    dependsOn(tasks.dokkaGenerate)
    archiveClassifier.set("javadoc")
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    includeEmptyDirs = false
    from(layout.buildDirectory.dir("dokka/html"))
  }

tasks.named<Jar>("sourcesJar") { exclude("**/*.bazel") }

publishing {
  publications {
    named<MavenPublication>("maven") {
      from(components["java"])

      artifact(javadocJar)

      pom {
        name.set("gRPC Kotlin Stub")
        artifactId = "grpc-kotlin-stub"
        description.set("Kotlin-based stubs for gRPC services")
      }
    }
  }
}