nested-multipart-spring-boot-starter/build.gradle at main · howtis/nested-multipart-spring-boot-starter · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.9.22'
    id 'com.vanniktech.maven.publish' version '0.34.0'
}

group = 'io.github.howtis'
version = project.findProperty('releaseVersion') ?: '1.0.0'

java {
    withSourcesJar()
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.compilerArgs.add('-parameters')
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        javaParameters = true
    }
}

repositories {
    mavenCentral()
}

dependencies {
    compileOnly 'org.springframework.boot:spring-boot-starter-web:3.2.0'
    compileOnly 'org.springframework.boot:spring-boot-starter-webflux:3.2.0'
    compileOnly 'com.fasterxml.jackson.core:jackson-databind:2.15.3'
    compileOnly 'jakarta.validation:jakarta.validation-api:3.0.2'

    testImplementation 'org.springframework.boot:spring-boot-starter-test:3.2.0'
    testImplementation 'org.springframework.boot:spring-boot-starter-web:3.2.0'
    testImplementation 'org.springframework.boot:spring-boot-starter-webflux:3.2.0'
    testImplementation 'org.springframework.boot:spring-boot-starter-validation:3.2.0'
}

test {
    useJUnitPlatform()
}

mavenPublishing {
    publishToMavenCentral(true)
    signAllPublications()
    //noinspection GroovyAssignabilityCheck
    pom {
        name = 'nested-multipart-spring-boot-starter'
        description = 'Spring Boot starter for nested multipart/form-data binding'
        url = 'https://github.com/howtis/nested-multipart-spring-boot-starter'
        licenses {
            license {
                name = 'MIT License'
                url = 'https://opensource.org/licenses/MIT'
            }
        }
        developers {
            developer {
                id = 'howtis'
                name = 'howtis'
                url = 'https://github.com/howtis'
            }
        }
        scm {
            url = 'https://github.com/howtis/nested-multipart-spring-boot-starter'
            connection = 'scm:git:git://github.com/howtis/nested-multipart-spring-boot-starter.git'
            developerConnection = 'scm:git:ssh://github.com/howtis/nested-multipart-spring-boot-starter.git'
        }
    }
}

tasks.named('jar') {
    metaInf {
        from rootProject.file('LICENSE')
    }
}