effect.odin

package rgbspace64

/*
	Файл реализует полноэкранные эффекты.
	В один момент времени используется только один эффект.
*/

import "vendor:raylib"
import "core:math/rand"
import "core:strings"
import "core:fmt"

// Перечисление типов эффектов.
effect_type_e :: enum {
	eft_none = 0,	// Эффект отсутствует.
	eft_fade_inc,	// Увеличивающееся затенение (альфа 255 -> 0). Поддерживает коллбэк.
	eft_fade_dec,	// Уменьшающееся затенение (альфа 0 -> 255). Поддерживает коллбэк.
	eft_wound,		// Получение урона.
	eft_new_level,	// Новый уровень.
	eft_pause		// Пауза
}	// effect_type_e

// Текущий эффект.
effect : effect_type_e = .eft_none;

// Внутренний счетчик кадров текущего эффекта.
@(private="file") frame_counter : u32 = 0;

// Внутренний коллбэк завершения эффекта.
@(private="file") effect_callback : proc( ) = nil;

// Процедура обработки
effect_update :: proc( ) {
	// Декремент счетчика кадров эффекта.
	if frame_counter > 0 do frame_counter -= 1;
} // effect_update

// Процедура отрисовки.
// Осуществляет отрисовку эффектов и обработку завершения эффекта (по завершению отрисовки кадра).
// Вызывает callback процедуры.
effect_draw :: proc( ) {
	// Если есть отображаемый эффект
	if effect != .eft_none {
#partial switch effect {
			// Увеличивающееся затенение (альфа 255 -> 0)
			case .eft_fade_inc :
				color_alpha : u8 = ( 255 - ( u8 )( frame_counter * 5 ) );
				background_color : raylib.Color = color_array[ ( color_e )( .col_void ) ];
				background_color.a = color_alpha;
				raylib.DrawRectangle( 0, 0, VIRTUAL_WINDOW_SIZE_X, VIRTUAL_WINDOW_SIZE_Y, background_color );
				
			// Уменьшающееся затенение (альфа 0 -> 255)
			case .eft_fade_dec :
				color_alpha : u8 = ( u8 )( frame_counter * 5 );
				background_color : raylib.Color = color_array[ ( color_e )( .col_void ) ];
				background_color.a = color_alpha;
				raylib.DrawRectangle( 0, 0, VIRTUAL_WINDOW_SIZE_X, VIRTUAL_WINDOW_SIZE_Y, background_color );
				
			// Получение урона
			case .eft_wound :
				color_alpha : u8 = ( u8 )( frame_counter * 17 );
				background_color : raylib.Color = color_array[ ( color_e )( .col_red ) ];
				background_color.a = color_alpha;
				raylib.DrawRectangle( 0, 0, VIRTUAL_WINDOW_SIZE_X, VIRTUAL_WINDOW_SIZE_Y, background_color );
				
			// Новый уровень
			case .eft_new_level :
				color_alpha : u8 = frame_counter > 30 ? 150 : ( u8 )( frame_counter * 5 );
				background_color : raylib.Color = color_array[ ( color_e )( .col_gray ) ];
				background_color.a = color_alpha;
				text_color : raylib.Color = color_array[ ( color_e )( .col_white ) ];
				text_color.a = color_alpha;
				
				raylib.DrawRectangle( 0, 30, VIRTUAL_WINDOW_SIZE_X, 5, background_color );
				
				// Получение строки.
				level_str : string = fmt.aprintf( "level %i", game_level );
				defer delete( level_str );
				
				// Получение строки в C стиле для отрисовки.
				level_str_cstr : cstring = strings.clone_to_cstring( level_str );
				defer delete( level_str_cstr );
				
				// Отрисовка текста номера уровня.
				font_draw_text( level_str_cstr, ( ( len( level_str ) ) == 7 ? 12.0 : 8.0 ), 30.0, text_color );
			
			// Пауза
			case .eft_pause :
				background_color : raylib.Color = color_array[ ( color_e )( .col_gray ) ];
				text_color : raylib.Color = color_array[ ( color_e )( .col_white ) ];

				raylib.DrawRectangle( 0, 30, VIRTUAL_WINDOW_SIZE_X, 5, background_color );
				
				// Получение строки.
				level_str : cstring = fmt.caprint( "pause" );
				defer delete( level_str );
				
				// Отрисовка текста номера уровня.
				font_draw_text( level_str, 15.0, 30.0, text_color );
				
				// Обработка счетчика кадров.
				if ( frame_counter == 1 ) do frame_counter = 2;
		} // switch effect
		
		// Если счетчик кадров текущего эффекта нулевой
		if ( frame_counter == 0 ) {
			// Сохранение эффекта в буфер и сброс эффекта.
			effect_buffer := effect;
			effect = .eft_none;
		
			// Если эффект поддерживает коллбэк и указатель на процедуру задан, вызов.
			if ( _has_callback( effect_buffer ) && ( effect_callback != nil ) ) do effect_callback( );
		}	// if frame counter == 0
	} // if effect
} // effect_draw

// Внутренняя процедура получения признака поддержки коллбэка эффектом.
@(private)_has_callback :: proc( effect_type : effect_type_e ) -> bool {
	return ( effect_type == .eft_fade_inc ) || ( effect_type == .eft_fade_dec ) || ( effect_type == .eft_wound );
}	// _has_callback

// Процедура дорбавления эффекта увеличивающегося затенения.
effect_add_fade_inc :: proc( callback_ptr : proc( ) ) {
	// Сохранение указателя на процедуру коллбэка.
	effect_callback = callback_ptr;
	
	// Инициализация эффекта.
	effect = .eft_fade_inc;
	frame_counter = 51;
}	// effect_add_fade_inc

// Процедура дорбавления эффекта уменьшающегося затенения.
effect_add_fade_dec :: proc( callback_ptr : proc( ) ) {
	// Сохранение указателя на процедуру коллбэка.
	effect_callback = callback_ptr;
	
	// Инициализация эффекта.
	effect = .eft_fade_dec;
	frame_counter = 52;
}	// effect_add_fade_dec

// Процедура добавления эффекта получения урона.
effect_add_wound :: proc( callback_ptr : proc( ) ) {
	// Сохранение указателя на процедуру коллбэка.
	effect_callback = callback_ptr;
	
	// Инициализация эффекта.
	effect = .eft_wound;
	frame_counter = 15;
}	// effect_add_wound

// Процедура добавления эффекта перехода на следующий уровень.
effect_add_new_level :: proc( ) {
	// Инициализация эффекта.
	effect = .eft_new_level;
	frame_counter = 120;
}	// effect_add_new_level

// Процедура добавления эффекта паузы. Действует перманентно.
effect_add_pause :: proc( ) {
	// Инициализация эффекта.
	effect = .eft_pause;
	frame_counter = 2;
}	// effect_add_pause

// Процедура добавления эффекта снятия паузы.
effect_remove_pause :: proc( ) {
	// Сброс счетчика кадров эффекта.
	if ( effect == .eft_pause ) do frame_counter = 0;
}	// effect_remove_pause